// BPSGR Sample1
// @author reco
// Copyrits 2009 reco
//
// BPSGRライブラリを使ったサンプルプログラム２
//
// 主な内容
// ドミノ倒しシミュレーション
// マウスクリックに応じて特定の物体に衝撃(impulse)を与える
//
// ソースは自由に使ってくださって結構です。
//

import processing.opengl.*;
import javax.media.opengl.*; 
import javax.media.opengl.glu.*;
import javax.vecmath.Vector3f;
import com.bulletphysics.dynamics.RigidBody;

import BPSGR.*;
PFont font;
BPSGR demo;
RigidBody rigid;

void setup()
{
  size(800, 600, OPENGL);
  font=createFont("FFScala", 32);
  
  PGraphicsOpenGL pgl = (PGraphicsOpenGL) g;  // g may change
  GL gl = pgl.beginGL();  // always use the GL object returned by beginGL

  demo = new BPSGR(this, gl);

  pgl.endGL();
  
  demo.initPhysics();

// 最初の１枚は、あとで衝撃を与えるので、RigidBodyクラスの変数に情報を保持しておく
  rigid = demo.AddBox(2f, new Vector3f(0, 5, 0), new Vector3f(0, 1, 0.5), 0, new Vector3f(10, 10, 1));
  
// ドミノ直線構成部分
  for(int i=1; i<50; i++)
  {
    demo.AddBox(2f, new Vector3f(0, 5, i*-7), new Vector3f(0, 1, 0.5), 0, new Vector3f(10, 10, 1));
  }

// ドミノ曲線構成部分
  for(int i=0; i<48; i++)
  {
    demo.AddBox(2f, new Vector3f(cos(radians(i*4))*-100+100, 5, sin(radians(i*4))*-100-350), new Vector3f(0, -1, 0), radians(i*5), new Vector3f(10, 10, 1));
  }
}

float[] pms = new float[10]; 
int n_pms = 0; 

Vector3f cameraPosition = new Vector3f(0f, 100f, 250f);
Vector3f cameraTargetPosition = new Vector3f(0f, 0f, 0f); // look at

void draw()
{
    background(208);
  GLU glu = new GLU();

    float ms = millis();

  if (demo.dynamicsWorld != null) {
    demo.dynamicsWorld.stepSimulation(ms / 1000f);
//    demo.dynamicsWorld.stepSimulation(ms / 1f);
  }

  PGraphicsOpenGL pgl = (PGraphicsOpenGL) g;  // g may change
  GL gl = pgl.beginGL();  // always use the GL object returned by beginGL

  BPSGR.setPerspective(gl, width, height);

  glu.gluLookAt(cameraPosition.x,cameraPosition.y,cameraPosition.z
                , cameraTargetPosition.x, cameraTargetPosition.y, cameraTargetPosition.z
                , 0, 1, 0);

  gl.glPushMatrix();  
  demo.render();
  gl.glPopMatrix();  

  pgl.endGL();

//--------------display fps ---------
//  println(millis());

  textFont(font,30.0);
  stroke(1,0,0);
 fill(200,0,0);
  int i;
  if(n_pms==10)
  {
    for(i=0; i<n_pms-1;i++)
    {
      pms[i] = pms[i+1];
    }
  }
 if(n_pms!=10)n_pms++;
 pms[n_pms-1] = ms;

 float fps = 0;
 
 for(i=0;i<n_pms-1;i++)
 {
   fps += 1/(pms[i+1]-pms[i]);
 }
  fps = ( fps / (n_pms-1))*1000;
  text("fps:"+int(fps),100,100);
//-----------------------

  textFont(font,16.0);
  text("Instrunction:",10,20);
  text("[1]-[4]:View Change",10,36);
  text("Mouse Click: Impulse to first object.",10,52);


}

void mouseClicked()
{
  Vector3f ret = new Vector3f(0f,0f,0f);
//  ret = getRayTo(mouseX, mouseY);

  // マウス座標から３D空間の座標を求める
  ret = BPSGR.getRayTo(mouseX, mouseY, cameraPosition, cameraTargetPosition, height, width);
  
  if(mouseButton == LEFT)
  {
  //保持していたRigidBodyに対して、衝撃(impulse)を加える
  //demo.addImpulse(rigid, 力の方向と強さ, 力点（物体のローカル座標で指定)
    demo.AddImpulse(rigid, new Vector3f(0,-0.5f,-1f), new Vector3f(0,10,-1));
  }
}

void keyPressed()
{
  switch(key)
  {
    //視点の変更
    case '1':
      cameraPosition = new Vector3f(0f, 100f, 250f);
      cameraTargetPosition = new Vector3f(0f, 0f, 0f);
    break;
    //視点の変更
    case '2':
      cameraPosition = new Vector3f(70f, 5, -201f);
      cameraTargetPosition = new Vector3f(0f, 0f, 0f);
    break;
    //視点の変更
    case '3':
      cameraPosition = new Vector3f(-100f, 80f, -600f);
      cameraTargetPosition = new Vector3f(0f, 0f, -350f);
    break;
    //視点の変更
    case '4':
      cameraPosition = new Vector3f(30f, 200, -30f);
      cameraTargetPosition = new Vector3f(0f, 0f, -100f);
    break;
    //視点の移動
    case 'q':
      cameraPosition.y += 1f;
    break;
    //視点の移動
    case 'a':
      cameraPosition.y -= 1f;
    break;
  }
}